- 資訊首頁(yè) > 開(kāi)發(fā)技術(shù) > web開(kāi)發(fā) > ASP >
- ASP程序中使用斷開(kāi)的數據記錄集的代碼
因此為了節省服務(wù)器資源，應該盡可能關(guān)閉連接以釋放連接所占有的資源，這種關(guān)閉記錄集的連接而不關(guān)閉記錄集的技術(shù)叫做斷開(kāi)記錄集，這個(gè)記錄集本身則稱(chēng)為斷開(kāi)的記錄集。
下面我們就通過(guò)一個(gè)實(shí)例來(lái)說(shuō)明這種技術(shù)的使用方法(NorthWind.mdb是Microsoft Access97自帶的一個(gè)數據庫，文件adovbs.inc可在C:\Program Files\Common Files\System\ADO下找到)：
代碼如下:
<% @LANGUAGE = VBScript %>
<!--#include file="adovbs.inc"-->
<%
Response.Expires = 0
Dim Cnn,objRS, strOut, strQ, strC
StrC= "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("\asp24") & "\NorthWind.mdb;"
'建立連接
Set Cnn = Server.CreateObject("ADODB.Connection")
Cnn.Open StrC
'創(chuàng )建Recordset對象
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.CursorLocation =adUseClient
objRS.CursorType = adOpenStatic
objRS.LockType = adLockOptimistic
strQ = "SELECT 運貨商ID, 公司名稱(chēng), 電話(huà) FROM 運貨商 "
objRS.Open strQ, Cnn, , , adCmdText
Set objRS.ActiveConnection = Nothing '斷開(kāi)記錄集
Cnn.Close '關(guān)閉連接
Set Cnn = Nothing
Response.Write "<HTML><BODY>"
'下面使用斷開(kāi)的記錄集
Do While (Not objRS.EOF)
strOut = objRS("運貨商ID") & ", " & objRS("公司名稱(chēng)") & ", " & objRS("電話(huà)")
Response.Write Server.HTMLEncode(strOut) & "<BR>"
objRS.MoveNext
Loop
Response.Write "<BR>準備新增或插入記錄: "
'若需要更新數據庫, 則要重新建立連接
Set Cnn = Server.CreateObject("ADODB.Connection")
Cnn.Open strC
Set objRS.ActiveConnection = Cnn
objRS.Filter = "公司名稱(chēng) = '吳豐'"
If objRS.EOF Then
objRS.AddNew
objRS("公司名稱(chēng)") = "吳豐"
objRS("電話(huà)") = "571-7227298"
objRS.Update
Response.Write "符合該條件的記錄不存在, 則新增.<BR>"
Else
objRS("電話(huà)") = "571-7227071"
Response.Write "符合該條件的記錄存在, 則 Update.<BR>"
objRS.Update
End If
Set objRS.ActiveConnection = Nothing
Cnn.close
Set Cnn = Nothing
objRS.Close
Set objRS = Nothing
Response.Write "</BODY></HTML>"
%>
免責聲明：本站發(fā)布的內容（圖片、視頻和文字）以原創(chuàng )、來(lái)自本網(wǎng)站內容采集于網(wǎng)絡(luò )互聯(lián)網(wǎng)轉載等其它媒體和分享為主，內容觀(guān)點(diǎn)不代表本網(wǎng)站立場(chǎng)，如侵犯了原作者的版權，請告知一經(jīng)查實(shí)，將立刻刪除涉嫌侵權內容，聯(lián)系我們QQ:712375056，同時(shí)歡迎投稿傳遞力量。
Copyright ? 2009-2022 56dr.com. All Rights Reserved. 特網(wǎng)科技 特網(wǎng)云 版權所有 特網(wǎng)科技 粵ICP備16109289號
域名注冊服務(wù)機構:阿里云計算有限公司（萬(wàn)網(wǎng)） 域名服務(wù)機構：煙臺帝思普網(wǎng)絡(luò )科技有限公司（DNSPod） CDN服務(wù)：阿里云計算有限公司 百度云 中國互聯(lián)網(wǎng)舉報中心 增值電信業(yè)務(wù)經(jīng)營(yíng)許可證B2
建議您使用Chrome、Firefox、Edge、IE10及以上版本和360等主流瀏覽器瀏覽本網(wǎng)站
