ASP下通過(guò)Adodb.Stream實(shí)現多線(xiàn)程下載大文件

有個(gè)朋友 做 某種小眾音樂(lè )交換站的（他們那個(gè)行業(yè)的昵圖網(wǎng)），需要用到付費下載。嘗試過(guò) 防盜鏈，不太理想，最終使用了 Adodb.Stream 讀取，直接輸出。

解決了 盜版的問(wèn)題，但是新的問(wèn)題又來(lái)了。Adodb.Stream 這種方式 電腦還好說(shuō)，大部分電腦瀏覽器都支持。移動(dòng)端 很多 瀏覽器為了 加速讀取，會(huì )多線(xiàn)程下載導致 文件無(wú)法正常讀取。

抓包，發(fā)現增加了 HTTP頭 HTTP_RANGE。隱約記得 之前讀過(guò) 王大（王洪影）的 《深入解析 ASP核心技術(shù)》當中提到ASP多線(xiàn)程下載的問(wèn)題，回家翻出來(lái)，最終還就真解決了。

為了 方便調用，直接寫(xiě)成了 一個(gè) 函數。沒(méi)用王大的代碼，感覺(jué)我自己的更美（自戀中…）。如有有需要的朋友需要，直接拿走即可，代碼如下：

option explicit
 
'inputFile 需要下載的文件
'outputName 輸出文件名，可以為空，為空時(shí)自動(dòng)根據 inputFile 生成
Sub CreateDownloader(byval inputFile, byval outputName)
  Dim filePath
  filePath = Server.Mappath(inputFile)
  If outputName = "" Then outputName = Split(filePath, "\")(UBound(Split(filePath, "\")))
 
  '下載開(kāi)始
  Dim AdoStream, bufferSize
  Set AdoStream = Server.CreateObject("Adodb.Stream") 'Adodb.Stream，實(shí)例變量名為了方便區分用大寫(xiě)
  bufferSize   = 2 * 1024 * 1024 '每次讀取大小(byte) 2M
  AdoStream.Mode = 3 '1 讀，2 寫(xiě)，3 讀寫(xiě)
  AdoStream.Type = 1 '1 二進(jìn)制，2 文本
  AdoStream.Open
  AdoStream.LoadFromFile(filePath) '載入文件
  Response.AddHeader "Content-Disposition", "attachment; filename=" & outputName '文件名
  Response.ContentType = "application/octet-stream" '通知瀏覽器接受的文件類(lèi)型(可自己定義,很多種,但一般都用這個(gè)
 
  Dim httpRange,rangeStart,fileSize
  '獲取 分段下載 請求
  httpRange = Request.ServerVariables("HTTP_RANGE")
  fileSize = AdoStream.size '文件總大小
 
  If httpRange = "" Then
    '不支持斷點(diǎn)續傳
    rangeStart = 0
  Else
    '支持斷點(diǎn)續傳
    httpRange = Mid(httpRange, 7)
    rangeStart = CLng(Split(httpRange, "-")(0))
 
    If rangeStart < 0 Or rangeStart >= fileSize Then
      '已經(jīng)下載完畢
      Response.Status = "416 Requested range not satisfiable"
    Else
      Response.Status = "206 Partial Content"
      Response.AddHeader "Content-Range", "bytes " & rangeStart & "-" & (fileSize - 1) & "/" & fileSize
      AdoStream.Position = rangeStart
    End If
 
  End If
 
  Dim binaryBlock
 
  If Response.Status <> "416 Requested range not satisfiable" Then
    Response.AddHeader "Content-Length", fileSize - rangeStart '通知瀏覽器接收的文件大小
    binaryBlock = AdoStream.Read(bufferSize)
 
    Do While Lenb(binaryBlock) > 0 '循環(huán)讀取直到讀完為止
      Response.BinaryWrite binaryBlock '輸出二進(jìn)制數據流
      Response.Flush '立即發(fā)送(要求至少256字節)，不加的話(huà)可能提示超過(guò)緩存區。
      binaryBlock = AdoStream.Read(bufferSize)
    Loop
 
  End If
 
  AdoStream.Close '關(guān)閉文件對象
  Set AdoStream = Nothing
  Response.End
End Sub

使用也非常簡(jiǎn)單，假如上面的代碼保存到了 downloader.asp，直接引用即可：

<!--#include file="downloader.asp"-->
<%
  '創(chuàng  )建下載
  call CreateDownloader("down/tools.rar", "")
   
  '創(chuàng  )建下載并自定義文件名
  call CreateDownloader("down/tools.rar", "hello.rar")
%>

有圖有真相：

到此這篇關(guān)于A(yíng)SP下通過(guò)Adodb.Stream實(shí)現多線(xiàn)程下載大文件的文章就介紹到這了,更多相關(guān)ASP多線(xiàn)程下載大文件內容請搜索腳本之家以前的文章或繼續瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！